Invoking the Flex Compiler via Native Process API in AIR 2.0

AIR 2.0 comes with the ability to interact with native processes. This means we can launch a process from the AIR application and communicate with its standard input/output. However, applications using the native process api must be packaged into native installer. Therefore, you must compile it separately in Windows, Mac and Linux to get 3 files as compared with 1 AIR file for all platforms.

Working the Native Process API is fairly easy. All the operations are performed using the NativeProcess class. To start a native process, you have to call the start method. The parameter passed to the start method is of type NativeProcessStartupInfo. This basically is used to represent the location of the process to be started and also to specify arguments(if any) for the process. I've created a very simple application which uses the Flex compiler (mxmlc) to compile an application.

First off, according to the Developer FAQ at Adobe Labs , bat files cannot be directly launched. Instead we launch the command prompt and then pass the command as input. Once a native process has started, we can write to its input and read from its output by using the standardInput and standardOutput objects. Here is a little screenshot of the application :



We get the location of the Flex SDK directory, the main application file and the output file. When the compile button is clicked, we create a compilation command using the three data (eg : /bin/mxmlc /app.mxml /app.swf) and execute the command. When the output is received, we use the file.openWithDefaultApplication() property to run the SWF file.

Note:
While running the application from the native installer, the command prompt also opens up beside it (which does not occur when you run from within Flash Builder).
Also note that this example assumes your application file has no errors. This is just a proof-of-concept to show how easy it is to build an application like this.

Resources :
AIR 2 (Adobe Labs)
Interacting with a native process (Adobe AIR Developer Center)

Here are the source files for the application :
The FXP file
The compiled native installer .exe file (Windows only)

There are still concerns about updating applications using native installers as the update framework will not work with this. I'm definitely looking forward to more cool demos from the community.

Creating Zip files with Adobe AIR with the nochump library

Following up on my previous post, here's how to archive a bunch of files and make a zip file.

After getting all the files you want to put in the archive, create a new ZipEntry object for each file and add it to a ZipOutput object using the putNextEntry() of the ZipOutput class. Then pass the ByteArray data of the file to the write() method of the ZipOutput class and close the entry by using the closeEntry() method. Finally, call the finish() method once you have done the same for all the files.

Here's the code snippet :

   import flash.events.FileListEvent;
   import flash.filesystem.*;
   
   import nochump.util.zip.*;
   
   private var zipInput:File = new File();
   private var zipOutput:File = new File();
   private var zipFile:ZipOutput;
   
   private var files:Array = new Array();
   
   private function loadFiles():void
   {
    zipInput.browseForOpenMultiple("Open ZIP file");
    zipInput.addEventListener(FileListEvent.SELECT_MULTIPLE, onSelect);
   }
   
   private function onSelect(e:FileListEvent):void
   {
    for(var i:uint = 0;i < e.files.length;i++)
    {
     var stream:FileStream = new FileStream();
     var f:File = e.files[i] as File;
     stream.open(f,FileMode.READ);
     var fileData:ByteArray = new ByteArray();
     stream.readBytes(fileData);
     var file:Object = new Object();
     file.name = f.name;
     file.data = fileData;
     files.push(file);
    }
   }
   
   private function createZIP():void
   {
    zipFile = new ZipOutput();
    for(var i:uint = 0; i < files.length; i++)
    {
     var zipEntry:ZipEntry = new ZipEntry(files[i].name);
     zipFile.putNextEntry(zipEntry);
     zipFile.write(files[i].data);
     zipFile.closeEntry();
    }
    zipFile.finish();
    
    zipOutput.browseForSave("Select target directory");
    zipOutput.addEventListener(Event.SELECT, onSave);
   }
   
   private function onSave(e:Event):void
   {
    var archiveFile:File = e.target as File;
    if(!archiveFile.exists)
    {
     var stream:FileStream = new FileStream();
     stream.open(archiveFile,FileMode.WRITE);
     stream.writeBytes(zipFile.byteArray);
     stream.close();
    }
   }

As usual you can download the project archive here. Happy experimenting :D

Extracting Zip files in Adobe AIR with the nochump library

Today, I'm going to show you how you can use the nochump library to extract zip files with Adobe AIR.

The ZipFile class constructor takes an IDataStream object as the parameter.Here you can use a ByteArray or a FileStream object which contains the data of the zip file. The entries property of the ZipFile object contains all the files in the archive as ZipEntry objects. Here the directory itself(excluding the files inside it) also counts as a ZipEntry object, so make sure to check using the isDirectory property of the ZipEntry object. Finally get the data of a single file using zipFile.getInput() method.

Here's the code :

   import flash.filesystem.*;
   import flash.net.FileFilter;
   
   import nochump.util.zip.*;
   
   private var zipInput:File = new File();
   private var zipOutput:File = new File();
   private var zipFile:ZipFile;
   
   private function loadZIP():void
   {
    var filter:FileFilter = new FileFilter("ZIP","*.zip");
    zipInput.browseForOpen("Open ZIP file",[filter]);
    zipInput.addEventListener(Event.SELECT, onSelect);
   }
   
   private function onSelect(e:Event):void
   {
    var stream:FileStream = new FileStream();
    stream.open(zipInput,FileMode.READ);
    
    zipFile = new ZipFile(stream);
    extract.enabled = true;
   }
   
   private function extractZIP():void
   {
    zipOutput.browseForDirectory("Select Directory for extract");
    zipOutput.addEventListener(Event.SELECT, onDirSelect);
   }
   
   private function onDirSelect(e:Event):void
   {
    for(var i:uint = 0; i < zipFile.entries.length; i++)
    {
     var zipEntry:ZipEntry = zipFile.entries[i] as ZipEntry;
     // The class considers the folder itself (without the contents) as a ZipEntry.
     // So the code creates the subdirectories as expected.
     if(!zipEntry.isDirectory())
     {
      var targetDir:File = e.target as File;
      var entryFile:File = new File();
      entryFile = targetDir.resolvePath(zipEntry.name);
      var entry:FileStream = new FileStream();
      entry.open(entryFile, FileMode.WRITE);
      entry.writeBytes(zipFile.getInput(zipEntry));
      entry.close();
     }
    }
   }

You can download the project archive here. Happy experimenting :D

AlivePDF Tutorial : How to create a PDF file with Flex/AIR

Here, we are going to see how to use the alivepdf library written by Thibault Imbert. This library allows us to create pdf content with Flex. In this tutorial, we will be using Adobe AIR in order to save the file. So lets get started. First create a new Flex project and select Desktop Application as the type. Download the AlivePDF library here. Copy the swc file and paste it in the libs folder. Now in the main application file, type the following code.

<?xml version="1.0" encoding="utf-8"?>  
<mx:WindowedApplication xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute">
    <mx:Script>  
        <![CDATA[ 
            import org.alivepdf.pdf.PDF;  
            import org.alivepdf.saving.Method;   
            import org.alivepdf.fonts.*;   
            import org.alivepdf.pages.Page;   
            import org.alivepdf.display.Display;   
            import org.alivepdf.layout.*; 

   private var pdf:PDF;  
            private var file:File; 
            [Embed( source="/assets/o-png24.png", mimeType="application/octet-stream" )]  
            private var pngBytes:Class; 
            public function generate ():void  
            { 
             var pdf:PDF = new PDF( Orientation.PORTRAIT, Unit.MM, Size.A4 ); 
                pdf.setDisplayMode( Display.FULL_PAGE, Layout.SINGLE_PAGE );
                var newPage:Page = new Page ( Orientation.PORTRAIT, Unit.MM, Size.A4 );
                pdf.addPage( newPage );
                pdf.setFont(FontFamily.ARIAL , Style.NORMAL, 12);
                pdf.addText("This is a sample text",5,15);
                pdf.drawCircle(25,35,15);
                pdf.addPage();
                pdf.addImageStream( new pngBytes() as ByteArray );
                var fs:FileStream = new FileStream();  
                file = File.desktopDirectory.resolvePath("testPage.pdf");   
                fs.open( file, FileMode.WRITE);   
                var bytes:ByteArray = pdf.save(Method.LOCAL);   
                fs.writeBytes(bytes);   
                fs.close();   
              }   
        ]]>   
    </mx:Script>
    <mx:Button click="generate()" label="Generate PDF" horizontalCenter="0" verticalCenter="0"/> 
</mx:WindowedApplication>

and Run the application.

The main class here is PDF. The addPage method adds a new page. Similarly, there are a lot of options such as addImage, addText and also graphic methods such as drawCircle. drawRect,etc.You can look at the documentation for this given in the zip file.

Happy experimenting